14. Bluetooth

The Bluetooth device name is LCKFB.

#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>

BLEServer *pServer = NULL;
BLECharacteristic * pTxCharacteristic;
bool deviceConnected = false;
bool oldDeviceConnected = false;
uint8_t txValue = 0;

#define SERVICE_UUID           "6E400001-B5A3-F393-E0A9-E50E24DCCA9E" // Service UUID
#define CHARACTERISTIC_UUID_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E" // Receive characteristic UUID
#define CHARACTERISTIC_UUID_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E" // Transmit characteristic UUID

// Service listener
class MyServerCallbacks: public BLEServerCallbacks {
    // When connected successfully
    void onConnect(BLEServer* pServer) {
      deviceConnected = true;
    };
    // When disconnected
    void onDisconnect(BLEServer* pServer) {
      deviceConnected = false;
    }
};

// Data listener
class MyCallbacks: public BLECharacteristicCallbacks {
    void onWrite(BLECharacteristic *pCharacteristic) {
      // Save the received data
      std::string rxValue = pCharacteristic->getValue();
      // If the received data length is greater than 0
      if (rxValue.length() > 0) {
        Serial.println("*********");
        Serial.print("Received Value: ");
        // Output the received data
        for (int i = 0; i < rxValue.length(); i++)
          Serial.print(rxValue[i]);
        // New line
        Serial.println();
        Serial.println("*********");
      }
    }
};

void setup() {
  // Start serial port 0 with a baud rate of 115200
  Serial.begin(115200);

  // Create a Bluetooth device named LCKFB
  BLEDevice::init("LCKFB");

  // Create a Bluetooth server
  pServer = BLEDevice::createServer();
  // Set listener
  pServer->setCallbacks(new MyServerCallbacks());

  // Create the BLE Service
  // Set Bluetooth service UUID
  BLEService *pService = pServer->createService(SERVICE_UUID);

  // Set transmit characteristic
  pTxCharacteristic = pService->createCharacteristic(
                    CHARACTERISTIC_UUID_TX,
                    BLECharacteristic::PROPERTY_NOTIFY
                  );

  // Set descriptor
  pTxCharacteristic->addDescriptor(new BLE2902());

  // Set receive characteristic
  BLECharacteristic * pRxCharacteristic = pService->createCharacteristic(
                       CHARACTERISTIC_UUID_RX,
                      BLECharacteristic::PROPERTY_WRITE
                    );

  // Set data listener
  pRxCharacteristic->setCallbacks(new MyCallbacks());

  // Start the server
  pService->start();

  // Start advertising
  pServer->getAdvertising()->start();

  // Serial prompt
  Serial.println("Waiting a client connection to notify...");
}

void loop() {

    // When a device is connected successfully
    if (deviceConnected) {
        // Set the transmit characteristic value to txValue, meaning txValue is the data source
        pTxCharacteristic->setValue(&txValue, 1);
        // Send notification, or send data
        pTxCharacteristic->notify();
        // Increment the value, range 0 to 255
        txValue++;
        // If too many packets are sent, the Bluetooth stack will become congested, so add a delay
        delay(100);
  }
    // After a device disconnects
    if (!deviceConnected && oldDeviceConnected) {
        delay(500); // Give the Bluetooth stack time to prepare
        pServer->startAdvertising(); // Restart advertising
        // Serial prompt for advertising start
        Serial.println("start advertising");
        oldDeviceConnected = deviceConnected;
    }
    // After a device connects successfully
    if ( deviceConnected && !oldDeviceConnected ) {
      // Serial prompt for successful connection
      Serial.println("connecting....");
    // do stuff here on connecting
        oldDeviceConnected = deviceConnected;
    }
}