MP3播放器模块

  该模块是一款小巧且价格低廉的MP3模块，可以直接接驳扬声器。模块配合供电电池、扬声器、按键可以单独使用，也可以通过串口控制，作为Arduino UNO或者是任何有串口的单片机的一个模块。模块本身集成了MP3、WAV、WMA的硬解码。同时软件支持TF卡驱动，支持FAT16、FAT32文件系统。通过简单的串口指令即可完成播放指定的音乐，以及如何播放音乐等功能，无需繁琐的底层操作使用方便,稳定可靠。

模块来源

采购链接：
https://detail.tmall.com/item.htm?_u=52t4uge5124c&id=609592993876&spm=a1z09.2.0.0.47582e8dqqFD4i
资料下载：
https://pan.baidu.com/s/17W4AL9TKMVLN4h5OCZWRTA
提取码：6bb7

规格参数

输入电压：3.3V~5V
额定电流：15mA
控制方式：串口
尺寸： 21(长)*21(宽)[]

使用说明

硬件接口

1. VCC（DFPlayer的电源正极）连接到开发板的5V。
2. GND（DFPlayer的电源负极）连接到开发板的GND。
3. TX（DFPlayer的发送端）连接到开发板的数字引脚10（RX）。
4. RX（DFPlayer的接收端）连接到开发板的数字引脚11（TX）。

使用方法

安装库 在arduino IDE中，搜索并安装 DFRobotDFPlayerMini 库。

编写代码

/******************************************************************************
  * 测试硬件：ColorEasyDuino开发板
  * 版 本 号: V1.0
  * 修改作者: www.lckfb.com
  * 修改日期: 2024年04月17日
  * 功能介绍:
  *****************************************************************************
  * 开发板软硬件资料与相关项目软硬件资料官网全部开源
  * 开发板官网：www.lckfb.com
  * 关注bilibili账号：【立创开发板】，掌握我们的最新动态！
  * 不靠卖板赚钱，以培养中国工程师为己任
******************************************************************************/
#include <SoftwareSerial.h>
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySerial(10, 11); // Arduino的10和11引脚分别作为RX和TX
DFRobotDFPlayerMini myDFPlayer;

void setup() {
  mySerial.begin(9600);
  Serial.begin(9600); // 开始串行通信，用于调试信息的输出

  if (!myDFPlayer.begin(mySerial)) {
    Serial.println(F("DFPlayer Mini 初始化失败！"));
    Serial.println(F("请检查连线，或确保SD卡正确插入。"));
    while (true);
  }
  myDFPlayer.volume(10);  // 设置初始音量为10
  Serial.println(F("DFPlayer Mini 准备就绪。"));
  Serial.println(F("发送命令：'p' - 播放, 's' - 停止, '+': 增大音量, '-': 减小音量, 'n': 下一曲, 't <track>': 播放指定曲目。"));
}

void loop() {
  if (Serial.available()) {
    String command = Serial.readStringUntil('\n'); // 读取串行端口接收到的完整命令行
    if (command == "p") {
      myDFPlayer.play();
      Serial.println("播放音乐");
    } else if (command == "s") {
      myDFPlayer.pause();
      Serial.println("暂停播放");
    } else if (command == "+") {
      myDFPlayer.volumeUp();
      Serial.println("增加音量");
    } else if (command == "-") {
      myDFPlayer.volumeDown();
      Serial.println("减小音量");
    } else if (command == "n") {
      myDFPlayer.next();
      Serial.println("下一曲");
    } else if (command.startsWith("t ")) {
      int track = command.substring(2).toInt(); // 提取曲目编号
      if (track > 0) {
        myDFPlayer.play(track);
        Serial.print("播放指定曲目：");
        Serial.println(track);
      } else {
        Serial.println("无效的曲目编号");
      }
    } else {
      Serial.println("未知命令");
    }
  }
}

使用验证

在SD卡中存入两首MP3歌曲。

上电后播放音乐。